一個電壓反饋放大器宏模型可以仿真共同效果，如瞬態響應、頻率響應、電壓噪聲和輸入/輸出壓擺率(slew rate)限制。接下來我們將以實例模型詳盡描述每個級和相關實際器件的行為。這里沒有提供完整的晶體管原理圖，客戶可以利用充分提取的3D器件模型進行精確的仿真來開發宏模型。
第一個關于運算放大器宏 模型的技術是由Boyle在1974年開發的，僅使用了兩個晶體管、幾個二極管和線性元件。[1]電阻、電容、電感器和電壓/電流控制源等線性元件的仿真 遠遠快于有源元件(active element)，并可用來提供極點、零點和任意增益。采用DC模型，可以用一個電壓控制電壓源作放大器，同時可以增加電阻以更好地表示輸入和輸出阻抗。電容、電感、二極管和晶體管可以提供適當的交流響應。欲了解更多關于仿真模型的開發信息，請參見參考文獻Alexander和Bowers[2]和[3]。他們的模型如本例后面所述。
ISL28133是一個采用電壓反饋拓撲結構的零漂移運算放大器。其增益帶寬積為400kHz，壓擺率為0.2V/微秒，電源電流為18μA。圖1顯示了一個五級模型，它代表了實際電路框圖。這些級包括輸入、增益、頻率整形、輸出和噪聲模塊。
圖1. ISL28133宏模型框圖
(圖字：輸入級，增益級，頻率整形級，輸出級，噪聲模塊)
輸入級
零漂移放大器的 輸入級如圖2所示。100μA的電流源“I2”饋送pmos輸入對。一般情況下，I2應選擇低于靜態電流。請記住，ISL28133的典型電源電流 (RL=open)僅為18μA。然而，很小的I2(約10μA)將使輸入電壓噪聲過大而無法仿真。這將在后面的噪聲分析部分討論。選擇 I2=100μA，并使用I1進行補償。Cin1和Cin2是輸入共模電容，Cdiff是差模輸入電容。
圖2. 輸入級
增益級
這一級可以執行模型中的一些重要功能
1)本級設置該部分的DC增益。所有后續級均可提供增益。
2)可實現壓擺率限制。
3)在AC特性中增加主極點(dominant pole)。
4)將信號從以電源作為參考量的兩個電壓水平移位至一個以中點作為參考量的單電壓。
5)限制輸出。
參見圖3，Ga是電路(block)G1和G2的增益。Gb是電路G3和G4的增益。
改變V3和V4的值可以限制壓擺率。此外，R8/C1和R7/C2決定了這一模式的主極點。E1用來在Vcc和Vee的中間設置參考電平。
圖3. 增益級
頻率整形級
這里采用的“伸縮”頻率整形技術是常見的運算放大器建模方法。它很容易增加更多的極點和零點。每個頻率整形電路可以提供增益。這個模型包含的零極對如圖4所示。
高階極點級G7/8、R13/14和C3/4如圖5所示。
圖4. 零極點對兒級
圖5. 高階極點級
噪聲仿真
ISL28133的輸入電流噪聲非常小(約70)，所以在這個模型中可以忽略不計。MOSFET的電壓噪聲可以用以下公式仿真：
ID是漏電流。高偏置電流需要低電壓噪聲。 在輸入級，尾電流設置得足夠高，以產生可以忽略的輸入電壓噪聲。在增加噪聲源之前，該模型將提供低于數據表中的規格或典型性能噪聲曲線的噪聲。圖6的噪聲 電壓模塊可通過使用一個偏置二極管-電阻器串聯組合的0.1V電壓源生成1/f和白噪聲。白噪聲是由熱噪聲電流產生的。
因此，給定噪聲電壓譜密度的所需電阻值為
該斬波穩定放大器設計可大大減少1/f噪聲。1/f噪聲(閃爍噪聲，flicker noise)指的是出現的與頻率成反比的功率譜密度噪聲。更為普遍的是，具有譜密度(
)的噪聲也稱為1/f噪聲。通常情況下，其中的穿越白噪聲曲線的頻率閃爍噪聲曲線被定義為拐角頻率(corner frequency)。少量的閃爍噪聲仍然可在SPICE二極管模型內進行建模，參見圖6。
圖6. 噪聲電壓模塊
輸出級
在頻率整形級之后，信號出現在節點VV5，它以兩個電源軌的中點作為參考量。每個受控源可以產生足夠的電流，以支持其并聯電阻兩端所需的電壓 降。R15和R16等于開環輸出電阻的兩倍，所以它們的并聯組合可提供正確的Zout。D5-D8和G9/10被用來迫使電流從正電壓軌 (positive rail)流向負電壓軌(negative rail)，以糾正實際電流流入或流出。
圖7. 輸出級
仿真結果
以下列出了某些SPICE仿真結果與來自手冊的典型性能曲線的比較(見右邊來自手冊的圖)。
圖8. 增益、頻率與CL的對比
(圖字：標準增益(dB)，頻率(Hz))
圖8是增益、頻率與負載電容的對比。它不是很準確，因為電路板上的寄生電容沒有列在模型中。其誤差小于5%。
圖9. 頻率響應與閉環增益對比
(圖字：增益(dB)，頻率(Hz))
圖9是具有不同增益的閉環增益頻率響應。在增益=100時，帶寬為3.94kHz，誤差小于5%。在低增益條件下，由于零極點對的緣故帶寬擴大。
圖10. 大信號階躍響應(4V)
(圖字：大信號(V)，時間(μs))
圖10是大信號階躍響應。仿真的壓擺率為0.198V/μs，誤差為1%。
結論
電壓反饋放大器全 面的SPICE宏模型包括諸如傳輸響應(transfer response)、準確的AC響應，DC偏移和電壓噪聲的影響。它很容易增加更多的功能，如共模抑制比(CMRR)、電源抑制比(PSRR)、輸入電流 噪聲等等。此外，它還可以方便地改變模型的參數，以適應其他的電壓反饋放大器。幾款Intersil的電壓反饋放大器采用了相同的模式拓撲結構。
ISL28133宏模型網表
* ISL28133宏模型
* B版本，2009年7月
* 該模型可仿真AC特性、電壓噪聲、瞬態響應
* 連接： +輸入
* | -輸入
* | | +電源電壓
* | | | -電源電壓
* | | | | 輸出
* | | | | |
.subckt ISL28133 3 2 7 4 6
*Input Stage
C_Cin1 8 0 1.12p
C_Cin2 2 0 1.12p
C_Cd 8 2 1.6p
R_R1 9 10 10
R_R2 10 11 10
R_R3 4 12 100
R_R4 4 13 100
M_M1 12 8 9 9 pmosisil
+ L=50u
+ W=50u
M_M2 13 2 11 11 pmosisil
+ L=50u
+ W=50u
I_I1 4 7 DC 92uA
I_I2 7 10 DC 100uA
*Gain stage
G_G1 4 VV2 13 12 0.0002
G_G2 7 VV2 13 12 0.0002
R_R5 4 VV2 1.3Meg
R_R6 VV2 7 1.3Meg
D_D1 4 14 DX
D_D2 15 7 DX
V_V3 VV2 14 0.7Vdc
V_V4 15 VV2 0.7Vdc
*SR limit first pole
G_G3 4 VV3 VV2 16 1
G_G4 7 VV3 VV2 16 1
R_R7 4 VV3 1meg
R_R8 VV3 7 1meg
C_C1 VV3 7 12u
C_C2 4 VV3 12u
D_D3 4 17 DX
D_D4 18 7 DX
V_V5 VV3 17 0.7Vdc
V_V6 18 VV3 0.7Vdc
*Zero/Pole
E_E1 16 4 7 4 0.5
G_G5 4 VV4 VV3 16 0.000001
G_G6 7 VV4 VV3 16 0.000001
L_L1 20 7 0.3H
R_R12 20 7 2.5meg
R_R11 VV4 20 1meg
L_L2 4 19 0.3H
R_R9 4 19 2.5meg
R_R10 19 VV4 1meg
*Pole
G_G7 4 VV5 VV4 16 0.000001
G_G8 7 VV5 VV4 16 0.000001
C_C3 VV5 7 0.12p
C_C4 4 VV5 0.12p
R_R13 4 VV5 1meg
R_R14 VV5 7 1meg
*Output Stage
G_G9 21 4 6 VV5 0.0000125
G_G10 22 4 VV5 6 0.0000125
D_D5 4 21 DY
D_D6 4 22 DY
D_D7 7 21 DX
D_D8 7 22 DX
R_R15 4 6 8k
R_R16 6 7 8k
G_G11 6 4 VV5 4 -0.000125
G_G12 7 6 7 VV5 -0.000125
*Voltage Noise
D_DN1 102 101 DN
D_DN2 104 103 DN
R_R21 0 101 120k
R_R22 0 103 120k
E_EN 8 3 101 103 1
V_V15 102 0 0.1Vdc
V_V16 104 0 0.1Vdc
.model pmosisil pmos (kp=16e-3 vto=10m)
.model DN D(KF=6.4E-16 AF=1)
.MODEL DX D(IS=1E-18 Rs=1)
.MODEL DY D(IS=1E-15 BV=50 Rs=1)
.ends ISL28133
參考文獻
1. BOYLE，G.R.，“集成電路運算放大器的宏建模”，IEEE J. 1974, SC-9。
2. Derek Bowers、Mark Alexander、Joe Buxton，“‘電流反饋’運算放大器的綜合仿真宏模型”，IEEE學報，137卷，1990年4月，137-145頁。
3. Mark Alexander、Derek Bowers，“符合AN-138 SPICE的運算放大器宏模型”，ADI公司，應用筆記138。
4. “用于‘電流反饋’放大器的全面SPICE宏模型AN-840的開發”，美國國家半導體公司，應用筆記840。